RFID-RC522+Bluetooth+초음파 센서 실험(아두이노)
RFID-RC522+Bluetooth+초음파 센서 실험(아두이노)
온라인 가상시뮬레이터 : https://www.tinkercad.com
참고 :
피에조부저 제어(아두이노)
서보모터 제어(아두이노)
Bluetooth 통신 제어(아두이노)
초음파센서 제어(아두이노)포스트 과정 :
RFID-RC522 제어(아두이노)
RFID-RC522 + Servo Motor 제어(아두이노)
RFID-RC522+Bluetooth+초음파 센서 실험(아두이노)
지난 시간에 RFID-RC522 + Servo Motor를 제어하는 실험을 하였습니다. 오늘은 몇가지 상황을 정하고 그 상황에 맞게 아두이노를 제어하는 실험을 하고자 합니다.
첫번째, 실험 내용은 RFID-RC522는 카드를 읽는 동작만 수행하는 아두이노와 Servo Motor를 회전 시키는 아두이노로 나누고 싶은 때가 있을 수 있습니다. 역할 분담으로 설계를 하고 싶을 때 그 문제를 해결 하기 위해서 두 아두이노 사이의 통신을 통해서 메세지를 주고 받으면 됩니다. 통신 중의 무선 통신 모듈인 Bluetooth 통신을 접목하여 실험을 하고 싶었습니다. 실제 실험의 내용은 Card가 저장된 UID랑 일치하면 Bluetooth를 통해 스마트폰에 메세지를 전송하는 과정을 실험 하였습니다. 이렇게 메세지를 전송할 수 있다면 다른 아두이노가 있으면 그 아두이노가 블루투스로 메세지를 수신하고 그에 따른 회전 명령을 수행하면 간단히 역할을 나눠서 동작할 수 있게 됩니다. 실제로 역할 분담 실험을 하기에는 부품이 부족하여 아쉽게 실험을 할 수 없고 해서 무선 통신으로 스마트폰에 메세지를 전송하는 데 까지만 실험을 해도 충분히 실험의 목적을 달성 할 수 있기 때문에 이정선에서 실험을 하기로 결정 했습니다.
두번째, 실험 내용은 RFID-RC522 리더기로 Card를 읽고 Servo Motor가 회전 되었을 때 다시 원위치로 되돌아 가게 하는 방법을 실험하고자 합니다. 실험에 쓰인 부품은 초음파센서 입니다. Servo Motor를 출입문이라고 가정하고 Card가 인식되면 180(Open)도 회전 후 사람이 출입문을 지나가고 나면 출입문을 통과 된 상황을 설정하면 자동으로 Servo Motor가 다시 0(Close)도 회전 되어 문이 닫히게 하면 좋을 것 같아서 상상해 보았습니다. 그 역할을 초음파센서를 이용할 예정입니다. 상상을 더하면 초음파센서가 인간이 지나기 전에 가지고 있는 거리측정값에서 인간이 지나가면 초음파센서의 거리측정값이 작아집니다. 인간를 감지한 값이 됩니다. 이때 초음파 센서값을 작아졌을 때 Servo Motor를 0(Close)도 회전 시켜서 문이 닫힌다는 설정입니다. 초음파센서의 위치는 안전위치에 문이 닫혀도 되는 위치에 설치 해야 겠지요.
1. RFID-RC522의 Bluetooth 통신
실험은 RFID-RC522 리더기로 Card를 인식하면 그 인식한 값을 Bluetooth를 이용하여 스마트폰에 전송하는 실험을 하겠습니다. 본 실험의 목적은 RFID-RC522 모듈을 사용하면서 이 모듈을 통해서 얻은 데이터를 외부 다른 기기로 전송하기 위해서 입니다. 지금 하고자 하는 실험은 Bluetooth 통신으로 외부로 기기(스마트폰)으로 RFID-RC522 리더기의 결과를 보낼 수 있다면 나중에 아두이노 두대로 나눠서 Bluetooth 통신으로 하나는 RFID-RC522 리더기 제어하고 하나는 Servo Motor제어를 하게 할 수 있게 됩니다.
![](https://steemitimages.com/600x600/https://i.imgur.com/Kmr4KZO.jpg)
1) RFID-RC522 + ServoMotor+피에조부저+Bluetooth 회로도
- 출처 : rfid-rc522 : https://github.com/miguelbalboa/rfid/tree/master/doc/fritzing
- 준비물 : RFID-RC522, Servo Motor, 피에조부저, Bluetooth, 아두이노우노
- 내용 : SPI 통신을 할 수 있게 핀은 연결하고 Servo Pin 7번, 피에조부저 6번으로 연결해 보자. 2,3번 핀을 Bluetooth핀으로 사용.
- 지난시간 회로도 참고 : RFID-RC522 제어(아두이노)
- BlueTX - arduinoRx - 2번
- BlueRX - arduinoTx - 3번
![](https://steemitimages.com/600x600/https://i.imgur.com/U7rtn1r.jpg)
지난 시간의 회로도에서 Bluetooth 모듈이 추가로 더 연결된 회로도 입니다. 2,3번 핀만 Bluetooth로 추가로 연결하시면 됩니다.
2) 코딩
- 내용 : RFID-RC522 리더기로 읽은 Card가 인식되면 Servo Motor를 회전 시키고 현재 상태 값을 Bluetooth를 이용하여 스마트폰에 메세지를 전송 시킨다.
- 참고 : https://playground.arduino.cc/Learning/MFRC522
- 출처 : miguelbalboa의 라이브러리 https://github.com/miguelbalboa/rfid
MFRC522
#include <SPI.h>
#include <MFRC522.h>
- MFRC522 mfrc522(SS_PIN, RST_PIN) : MFRC522 인스턴스화
- SPI.begin() :SPI bus 초기화
- mfrc522.PCD_Init() : MFRC522 card 초기화
- mfrc522.PICC_IsNewCardPresent() : 새카드 확인
- frc522.PICC_ReadCardSerial() : 하나의 카드읽기 확인
- rfid.uid.uidByte[] : 읽은 카드 키값이 들어 있음
피에조 부저
- tone(tonePin ,음,음길이) : 음 시작
- noTone(tonePin ) : 음 중지
Servo Motor
#include <Servo.h>
- Servo servo : 서보모터 객체 선언
- servo.attach(서보핀) : 서보 모터에 출력을 담당할 핀 선언
- servo.write(회전각) : 회전각 만큰 서보모터를 회전 시킴
시리얼 통신
- Serial.begin(9600) : 시리얼 통신 시작(9600 통신속도)
- Serial.println(값) : 시리얼모니터 출력
- Serial.available() : 시리얼통신으로 데이터가 들어놨는지 상태 확인
- Serial.parseInt() : Int형으로 데이터를 읽음
Bluetooth(SoftwareSerial 통신)
#include <SoftwareSerial.h>
SoftwareSerial mySerial (rx, tx) : 소프트시리얼 객체선언(rx(수신), tx(전송))
mySerial.begin(9600) : 시리얼 통신 시작(예로 9600 통식속도를 사용해 봤네요.)
mySerial.println(값) : 데이터 전송
지난 시간 소스에서 Bluetooth를 다음과 SfotwareSerial 명령들을 추가하면 됩니다. 간단히 Serial 부분을 SoftwareSerial 형태로 변경만 해주시면 됩니다.
SoftwareSerial mySerial (rx, tx) : 소프트시리얼 객체선언(rx(수신), tx(전송))
이렇게 통신객체변수 mySerial로 선언을 해주면 다음과 같이 표현만 해주시면 됩니다.
Serial.begint(9600) => mySerial.begin(9600)
Serial.println("Open") => mySerial.println("Open")
Serial.println("Close") => mySerial.println("Close")
이렇게 SoftwareSerial 통신을 하면 됩니다.
Bluetooth 부분을 추가하여 수정 하면 다음과 같습니다.
[소스]
#include <SPI.h>
#include <MFRC522.h>
#include <Servo.h>
#include <SoftwareSerial.h>
const int RST_PIN = 9;
const int SS_PIN = 10;
MFRC522 mfrc522(SS_PIN, RST_PIN); // MFRC522 인스턴스
byte cardkeyByte[4] = {0x55, 0xAF, 0x07, 0x88}; //card UID
boolean state = false; //Servo Motor 상태값
Servo servo;
const int SERVO_PIN = 7;
const int TONEPIN = 6;
const int rxPin = 2;
const int txPin = 3;
SoftwareSerial mySerial(rxPin, txPin); // RX, TX
void setup() {
Serial.begin(9600);
while (!Serial);
mySerial.begin(9600);
SPI.begin(); //SPI 시작
mfrc522.PCD_Init(); //MFRC522 card 초기화
Serial.println(F("Warning: this example clears your mifare UID, use with care!"));
servo.attach(SERVO_PIN);
servo.write(0);
delay(50);
}
void loop() {
// 새 카드 확인
if ( ! mfrc522.PICC_IsNewCardPresent()) return;
// 카드 읽기
if ( ! mfrc522.PICC_ReadCardSerial()) return;
//카드 확인 메세지 음
tone(TONEPIN ,523,1000/8); // 도음으로 8분음표(음길이)
delay(1000/4*1.30);
noTone(TONEPIN);
//읽은 Card UID와 등록된 Card UID가 일치하는 확인
if (mfrc522.uid.uidByte[0] == cardkeyByte[0] && mfrc522.uid.uidByte[1] == cardkeyByte[1] &&
mfrc522.uid.uidByte[2] == cardkeyByte[2] && mfrc522.uid.uidByte[3] == cardkeyByte[3] ){
state=!state;
if(state == true){
Serial.println("Open");
mySerial.println("Open");
servo.write(180);
delay(1000);
}
else{
Serial.println("Close");
mySerial.println("Close");
servo.write(0);
delay(1000);
}
delay(2000);
}
}
2) 결과
아두이노 IDE 시리얼모니터로 "Open" or "Close" 메세지 출력
![](https://steemitimages.com/450x450/https://i.imgur.com/q2WbgMZ.jpg)
실제 블루투스로 스마트폰에 깔리 블루투스 앱에 "Open" or "Close" 메세지 출력
![](https://steemitimages.com/450x450/https://i.imgur.com/32I6utG.jpg)
작동 동영상 결과는 다음과 같습니다.
2. RFID-RC522 + 초음파 센서
- 참고 : 초음파센서 제어(아두이노)
RFID-RC522 모듈로 출입문이 열리고 닫히는 동작을 한다고 상상을 해보세요. 이때 출입문에 RFID-RC522 Card를 대면 Servo Motor를 180도 회전 시켜서 "Open" 상태가 되고 출입문를 지나가면 자동으로 Servo Motor가 0도로 회전 시켜서 "Close" 상태를 만든 다면 좀 더 그럴싸 해지겠죠. 이 표현을 하기 위해서 여러 Sensor 중 초음파 Sensor를 사용하여 그 느낌을 표현 하고자 합니다. 즉, 출입문을 지나고 출입문이 닫혀도 되는 안전지점에 초음파 Sensor를 배치하고 인간 감지를 통해 출입문을 자동으로 닫히게 한다는 설정으로 상상을 해 보았습니다. 물론 이 경우는 상황 조건 변수들을 다 고려한다면 좀 복잡해지지만 최대한 단순하게 의미만 전달하는 실험을 하는게 목적임으로 단순하게 접근하고 단순한 동작만 수행되도록 실험 하겠습니다.
실제로 모형을 만들어서 실험을 하면 좋은데 손재주가 없어서 못 만들었네요. 대충 그 의미만 전달하는 실험으로 Card를 RFID-RC522모듈에 대면 Servo Motor가 180도 회전을 하고 초음파 Sensor가 측정한 거리값을 일정 수치 이하면 인간을 감지한 걸로 판정하고 Servo Motor를 0도로 회전시키는 실험으로 그 느낌을 대신 전달하고자 합니다.
![](https://steemitimages.com/600x600/https://i.imgur.com/y2bzZFO.jpg)
1) RFID-RC522 + 초음파 센서 회로도
- 출처 : Bluetooth HC-06 : https://github.com/RafaGS/Fritzing/blob/master/Bluetooth%20HC-06.fzpz
부품이 하나씩 늘어날 때마다 회로도가 지져분 해지네요. 처음에는 초음파센서 두개로 연결해서 상황을 하나 더 만들려고 했는데 엄청 지져분 해져서 한개의 초음파 센서로 단순하게 초음파센서로 읽은 거리값으로 동작하게 표현하여 최대한 코딩량을 줄였네요.
![](https://steemitimages.com/600x600/https://i.imgur.com/ixcDcwy.jpg)
2) 코딩
- 내용 : RFID-RC522 리더기로 읽은 Card가 인식되면 Servo Motor를 180도 회전 시키고 초음파 센서로 일정거리값이하면 Servo Motor를 0도로 회전 시킨다.(거리값=10cm 실험)
위 소스를 약간만 변경하겠습니다.
//읽은 Card UID와 등록된 Card UID가 일치하는 확인
if (mfrc522.uid.uidByte[0] == cardkeyByte[0] && mfrc522.uid.uidByte[1] == cardkeyByte[1] &&
mfrc522.uid.uidByte[2] == cardkeyByte[2] && mfrc522.uid.uidByte[3] == cardkeyByte[3] ){
state=!state;
if(state == true){
Serial.println("Open");
mySerial.println("Open");
servo.write(180);
delay(1000);
}
else{
Serial.println("Close");
mySerial.println("Close");
servo.write(0);
delay(1000);
}
delay(2000);
}
위 소스에서 필요한 동작은 Card가 일치하면 문만 열기게 하면 되니깐 else 이하문은 필요 없습니다. 이 부분은 초음파센서 코딩으로 넘기게 됩니다.
if (mfrc522.uid.uidByte[0] == cardkeyByte[0] && mfrc522.uid.uidByte[1] == cardkeyByte[1] &&
mfrc522.uid.uidByte[2] == cardkeyByte[2] && mfrc522.uid.uidByte[3] == cardkeyByte[3] ){
state=true;
Serial.println("Open");
mySerial.println("Open");
servo.write(180);
delay(1000);
}
이렇게 해서 Card가 읽치하면 무조건 Servo Motor는 180도로 향하게 됩니다. 여기서 state 상태변수를 그냥 남겨둿는데 이것은 초음파센서 진입 변수로 재활용 할 예정입니다. 즉, Card를 대고 문이 열렸을 때만 초음파센서를 작동시킨다고 보시면 됩니다.
초음파 센서핀은 Trig, Echo핀이 있는데 Trig은 초음파를 쏘는 핀이고 Echo은 초음파를 읽는 핀입니다.
const int TRIG_PIN = 4;
const int ECHO_PIN = 5;
남는 핀중에 4,5번핀을 그냥 선택했습니다.
void setup(){
pinMode(TRIG_PIN,OUTPUT); //초음파센서핀(TRIG)
pinMode(ECHO_PIN,INPUT); //초음파센서핀(ECHO)
}
그리고 Trig(OUTPUT), Echo(INPUT)핀을 어떤 모드로 사용할 것인지 선언해야 합니다.
if(state == true){
float distance = UltrasonicDistance();
if(distance<10){
state=false;
Serial.print("Close : ");
Serial.println(distance);
mySerial.println("Close");
servo.write(0);
delay(500);
}
}
state로 Card가 일치하면 문이 열리잖아요 그때 state가 true가 되니깐 초음파센서는 그 때부터서 초음파 센서가 동작해야 하기 때문에 이렇게 if문으로 "state==true"일 때 UltrasonicDistance()함수로 초음파 센서를 측정하겠다는 로직입니다. UltrasonicDistance()함수는 사용자정의함수로 직접 만든함수명입니다.
float UltrasonicDistance(){
digitalWrite(TRIG_PIN, LOW);
delayMicroseconds(2);
digitalWrite(TRIG_PIN,HIGH);
delayMicroseconds(10);
digitalWrite(TRIG_PIN,LOW);
float duration = pulseIn(ECHO_PIN, HIGH);
return duration / 57.5;
}
초음파 측정 로직인데 이 로직은 기본 아두이노홈페이지에 가시면 측정하는 코딩 로직을 예제로 소개하고 있습니다. 그 부분을 묶어서 캡슐화 해서 사용자정의 함수로 분리해 냈습니다. 이 코딩을 loop()안에다가 전부 코딩하면 오히려 가독성이 떨어지기 때문에 사용자정의함수로 분리를 한 것이죠.
if(distance<10){
거리가 10cm이하면 참;
state = false;
servo.write(0);
delay(500);
}
거리가 10cm이하면 문이 닫힌다는 설정문입니다. 그러면 문이 닫히면 더이상 초음파센서 측정이 필요 없으니깐 state=false로 바꾸어 주면 다시 문이 열리기 전까지는 초음파 측정을 할 필요가 없겠죠. state가 초음파센서 작동 진입 락이라고 생각하시면 됩니다.
초음파센서 로직의 대한 코딩 배치를 하면 종합 코딩은 다음과 같습니다. 새카드확인과 카드읽기 전에 초음파센서를 동작시킬건지 말건지를 먼저 수행되도록 배치 했습니다. 그 이유는 새카드확인과 카드읽기가 만족하지 않으면 거기서 return 되기 때문에 새카드확인과 카드읽기 문장 아래에 배치하면 카드를 대기 전까지 초음파센서는 측정하지 못하게 됩니다. 그래서 먼저 배치 한 것이죠. 그리고, state 상태변수로 초음파센서를 작동 상태값으로 초음파센서를 제어하게 됩니다.
[소스]
#include <SPI.h>
#include <MFRC522.h>
#include <Servo.h>
#include <SoftwareSerial.h>
const int RST_PIN = 9;
const int SS_PIN = 10;
MFRC522 mfrc522(SS_PIN, RST_PIN); // MFRC522 인스턴스
byte cardkeyByte[4] = {0x55, 0xAF, 0x07, 0x88}; //card UID
boolean state = false; //초음파 센서 작동 상태값
Servo servo;
const int SERVO_PIN = 7;
const int TONEPIN = 6;
const int rxPin = 2;
const int txPin = 3;
SoftwareSerial mySerial(rxPin, txPin); // RX, TX
const int TRIG_PIN = 4;
const int ECHO_PIN = 5;
void setup() {
Serial.begin(9600);
while (!Serial);
mySerial.begin(9600);
SPI.begin(); //SPI 시작
mfrc522.PCD_Init(); //MFRC522 card 초기화
Serial.println(F("Warning: this example clears your mifare UID, use with care!"));
pinMode(TRIG_PIN,OUTPUT); //초음파센서핀(TRIG)
pinMode(ECHO_PIN,INPUT); //초음파센서핀(ECHO)
servo.attach(SERVO_PIN);
servo.write(0);
delay(50);
}
void loop() {
if(state == true){
float distance = UltrasonicDistance();
if(distance<10){
state=false;
Serial.print("Close : ");
Serial.println(distance);
mySerial.println("Close");
servo.write(0);
delay(500);
}
}
// 새 카드 확인
if ( ! mfrc522.PICC_IsNewCardPresent()) return;
// 카드 읽기
if ( ! mfrc522.PICC_ReadCardSerial()) return;
//카드 확인 메세지 음
tone(TONEPIN ,523,1000/8); // 도음으로 8분음표(음길이)
delay(1000/4*1.30);
noTone(TONEPIN);
//읽은 Card UID와 등록된 Card UID가 일치하는 확인
if (mfrc522.uid.uidByte[0] == cardkeyByte[0] && mfrc522.uid.uidByte[1] == cardkeyByte[1] &&
mfrc522.uid.uidByte[2] == cardkeyByte[2] && mfrc522.uid.uidByte[3] == cardkeyByte[3] ){
state = true;
Serial.println("Open");
mySerial.println("Open");
servo.write(180);
delay(500);
}
}
float UltrasonicDistance(){
digitalWrite(TRIG_PIN, LOW);
delayMicroseconds(2);
digitalWrite(TRIG_PIN,HIGH);
delayMicroseconds(10);
digitalWrite(TRIG_PIN,LOW);
float duration = pulseIn(ECHO_PIN, HIGH);
return duration / 57.5;
}
3) 결과
아두이노 IDE 시리얼모니터로 "Open" or "Close" 메세지 출력과 함께 초음파센서가 측정된 거리(Cm)을 동시에 출력 합니다.
![](https://steemitimages.com/450x450/https://i.imgur.com/YjcxeNn.jpg)
스마트폰에는 이전 소스와 동일하게 "Open" or "Close" 메세지 출력 합니다.
![](https://steemitimages.com/450x450/https://i.imgur.com/EseCaiP.jpg)
동작 동영상은 다음과 같습니다.
마무리
RFID-RC522 모듈에 부품이 하나씩 늘어나면서 코딩량이 좀 많이 늘어 났습니다. 만약, 처음부터 이렇게 회도도를 만들고 코딩량이 길었다면 아마도 RFID-RC522 모듈에 대해 이해하기가 힘들었을 꺼에요. 그리고, 이전 post를 읽지 않는다면 오늘 post가 어려울 수도 있으니깐 꼭 읽고 이 post를 보셨으면 합니다.
최근의 post를 계속 중복된 실험이 이루어지고 있는데 그 중복되 실험 의미를 잘 이해하시고 따라오셔야 합니다. 대개 개별적인 부품 실험은 쉽게 이해하시는데 2개 이상의 부품이 결합하면 어떻게 코딩해야 할지 이해하지 못하는 경우가 많습니다. 어디에 어느 명령 코딩을 삽입해야 하는지를요. RFID-RC522 모듈을 이렇게 작동합니다. 하고 끝내면 사실 이 모듈로 상상을 하더라도 다른 부품과 연결 하기는 초보분들은 쉽지 않습니다. 여러개의 부품을 연결하면 코딩에 멘붕이 발생하기도 합니다. 제가 실험한 과정을 잘 보시고 어떤 과정으로 회로도를 만들고 코딩을 했는지 이해하셨으면 합니다.
RFID-RC522 부품을 하나에서 출발해서 여기까지 왔습니다. 부족한 부분이 많고 추가해야 할 부품은 많지만 상상의 상상을 더하면 위 회로도가 아닌 여러분만의 회로도를 만들 수 있으니깐 RFID-RC522 모듈 하나에서 다시 처음부터 여러분들이 회로도를 만들고 상황을 설정하고 그 상황의 회로도를 만들고 그 상황의 코딩을 한번 해보셨으면 합니다.
코딩이란 00이다. 이렇게 아주 단순하게 정의하면, 어떻게 정의할 수 있을까요?
참 난해한 질문이네요!
저에게 있어서 코딩은 기계에 생명을 불어넣는 것라고 생각되네요. 프로그래머는 창조자라 생각합니다.
아두이노로 살펴보면 아두이노 자체로는 하나의 칩일 뿐이죠. 거기에 초음파센서와 같은 부품을 결합하여 앞을 볼 수 있고 마이크사운드감지센서로 소리를 들을 수 있고 스피커로 소리를 낼 수 있으며 근육센서 등 여러 인체센서로 외부의 감각을 느낄 수 있으며 gas 센서와 같은 특수 센서로 냄새를 맡을 수 있으며 Motor로 움직일 수 있습니다.
이런것들이 코딩에 의해서 아두이노에 생명을 불어 넣는 작업인 것이죠, 코딩은 좀 더 인간적 행동과 사고에 가깝게 기계에 지능을 갖게 하는 작업이라고 생각합니다.
넵. 쉽게 이해가 됩니다. 감사합니다.
점점 복잡해지네요, 초음파센서에 블루투수까지... 공부가 많이 됩니다.
부품 한두개만 늘려도 복잡해져 버려서 post하가기 고민되네요. 여기서 몇개 더 추가하면 좋은데 너무 복잡해질 것 같아서 최대한 줄인게 이거네요 ^^
아 또 추가할 게 있나요?
몇가지 더 추가하고 코딩에서 좀 더 다듬고 상황을 더 만들어야 해요.
의미 전달 설계와 코딩을 하다 보니깐 여기서 멈췄지만요.
예를 들면요 초음파센서의 위치에 사람이 지나가서 문이 닫힐려는 찰라에 누군가 문을 열고 들어오는 도중일 경우도 있고요. 그러면 초음파 센서로만 무조건 문을 닫게 해서는 안되고요. 출입문 입구에서도 딜레이들 주든지 아니면 초음파센서를 더 달아서 혹시 뒷사람이 문을 통하중인지에 대한 상황 코딩을 또 해야 겠지요.
그외도 몇가지 더 있지만 사실 그렇게 코딩을 늘리면 더 복잡해지고 의미전달이 안될 것 같아서 다 빼버리고 최소한의 의미만 전달할 수 있도록 회로도랑 코딩을 한 것이죠.
추가하고 싶은 부품이 좀 있었는데 그 부품이 없네요. 초음파 센서는 2개정도 있어서 두개를 연결해서 그 상황을 만들어 볼까도 했는데 코딩이 좀 더 늘어나서 복잡해 보일 것 같아서 초음파 센서는 한개만 연결했네요.
오늘 한 것은 딱 뭔가를 표현하기 위한 첫걸을을 내딛은 거라고 생각하시면 될 듯 싶네요. 진짜로 뭔가를 만든다면은 추가할 것이 많을 듯 싶네요.
짱짱맨 호출에 출동했습니다!!
짱짱맨 방문에 언제나 고맙습니다.